home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / PET / S-Super PET / (s)t2.d64 / DISAS.ASM < prev    next >
Encoding:
Assembly Source File  |  2009-01-18  |  18.5 KB  |  859 lines
  1.         nam     ** disas.asm ** sp9000  82/10/25
  2. ;     Byte feb 82 (start address in x register)
  3. outch   rmb     2
  4. curadr  rmb     2
  5. wrkadr  rmb     2
  6. length  rmb     1
  7. page1   rmb     1
  8. opcd    rmb     1
  9. postb   rmb     1
  10. byte1   rmb     1
  11. byte2   rmb     1
  12. indflg  rmb     1
  13. indbyt  rmb     1
  14. nxtbuf  rmb     2
  15. buffer  equ     *
  16.         rmb     4
  17.         rmb     1
  18.         rmb     2
  19.         rmb     2
  20.         rmb     2
  21.         rmb     1
  22. hexb    rmb     4
  23.         rmb     2
  24. mnem    rmb     5
  25.         rmb     1
  26. oprand  rmb     21
  27. endbuf  equ     *
  28.         org $0
  29.         xref getchar_
  30.         xref initstd_
  31.         xref putchar_
  32.         xref crt
  33.         jsr  initstd_
  34.         ldx     #text
  35.         loop
  36.           ldb   ,x+     ;load char in b
  37.           quif  eq
  38.           pshs  x
  39.           jsr   putchar_;display char
  40.           puls  x
  41.         endloop
  42. stp     swi
  43. lp9     ldb     #$17    ;disassemle 23 lines
  44. lp8     lbsr    disas9
  45.         decb
  46.         bne     lp8
  47. inchar  pshs    x
  48.         jsr     getchar_
  49.         puls    x
  50.         cmpb    #'q     ; quit if q
  51.         beq     stp
  52.         cmpb    #'^     ; uparrow backup $80
  53.         beq     backup
  54.         cmpb    #'p     ; print screen
  55.         beq     crtdmp
  56.         cmpb    #$0d    ; press <cr> to continue
  57.         beq     lp9
  58.         cmpb    #'f
  59.         bhi     inchar  ; branch if higher
  60.         cmpb    #'0
  61.         blo     inchar  ; branch if lower
  62.         cmpb    #'a
  63.         bhs     itshexa
  64.         cmpb    #'9
  65.         bls     itshex
  66.         bra     inchar
  67. backup  ldd     #$ff80
  68.         leax    d,x
  69.         bra     inchar
  70. itshexa addb    #9
  71. itshex  andb    #$0f    ;get rid of ascii
  72.         lda     #4
  73.         stx     $0186
  74. lp7     asl     $0187
  75.         rol     $0186
  76.         deca
  77.         bne     lp7
  78.         ldx     $0186
  79.         abx
  80.         bra     inchar
  81. crtdmp  jsr     crt
  82.         bra     inchar
  83. text    fcc "Using monitor load in the x register the disassembly "
  84.         fcc "starting address,then press  g pcr+1 <cr>."
  85.         fcc " Use hexnumber <cr> for new location, <cr> for next screen,"
  86.         fcc " p <cr> for printout, ^<cr> for backing up and q <cr> for "
  87.         fcb 0
  88. disas9  pshs    a,b,y,u
  89.         opt     nolist
  90.         leau    outch-endbuf,s
  91.         tfr     u,s
  92.         stx     curadr,u
  93.         sty     outch,u
  94.         leax    length,u
  95.         ldb     #buffer-length
  96. init1   clr     ,x+
  97.         decb
  98.         bne     init1
  99.         lda     #$20
  100.         ldb     #endbuf-buffer
  101. init2   sta     ,x+
  102.         decb
  103.         bne     init2
  104.         ldx     curadr,u
  105.         stx     wrkadr,u
  106.         inc     length,u
  107.         ldb     ,x+
  108.         cmpb    #$10
  109.         beq     main1
  110.         cmpb    #$11
  111.         bne     main2
  112. main1   stb     page1,u
  113.         inc     length,u
  114.         ldb     ,x+
  115. main2   stx     wrkadr,u
  116.         stb     opcd,u
  117.         cmpb    #$80
  118.         bhs     main3
  119.         cmpb    #$40
  120.         blo     main4
  121.         andb    #$0f
  122.         bra     main4
  123. main3   andb    #$0f
  124.         orb     #$40
  125. main4   lda     #4
  126.         mul
  127.         leax    mntab,pc
  128.         leax    d,x
  129.         leay    mnem,u
  130.         ldb     #4
  131. main5   lda     ,x+
  132.         sta     ,y+
  133.         decb
  134.         bne     main5
  135.         leax    oprand,u
  136.         stx     nxtbuf,u
  137.         lda     mnem,u
  138.         cmpa    #'*
  139.         lbeq    ilegop
  140.         lda     opcd,u
  141.         cmpa    #$c0
  142.         lbhs    opc0
  143.         cmpa    #$80
  144.         lbhs    op80
  145.         cmpa    #$40
  146.         bhs     op00
  147.         cmpa    #$30
  148.         lbhs    op30
  149.         cmpa    #$20
  150.         lbhs    op20
  151.         cmpa    #$10
  152.         bhs     op10
  153.         bra     op00
  154. op00    tst     page1,u
  155.         bne     op01
  156.         cmpa    #$4e
  157.         beq     op01
  158.         cmpa    #$5e
  159.         bne     op02
  160. op01    lbra    ilegop
  161. op02    anda    #$f0
  162.         ldb     #'a
  163.         cmpa    #$40
  164.         beq     op03
  165.         cmpa    #$50
  166.         bne     op04
  167.         ldb     #'b
  168. op03    stb     mnem+3,u
  169.         bra     op07
  170. op04    cmpa    #$60
  171.         bne     op05
  172.         lbsr    index
  173.         bra     op07
  174. op05    cmpa    #$70
  175.         bne     op06
  176.         lbsr    extend
  177.         bra     op07
  178. op06    lbsr    direct
  179. op07    lbra    finish
  180. op10    ldb     page1,u
  181.         beq     op12
  182. op11    lbra    ilegop
  183. op12    cmpa    #$16
  184.         beq     op13
  185.         cmpa    #$17
  186.         bne     op14
  187. op13    lbra    op23
  188. op14    cmpa    #$1a
  189.         beq     op15
  190.         cmpa    #$1c
  191.         bne     op17
  192.         lda     #'c
  193.         sta     mnem+4,u
  194. op15    lda     #'#
  195.         lbsr    putch
  196.         lbsr    direct
  197. op16    lbra    finish
  198. op17    cmpa    #$1e
  199.         blo     op16
  200.         inc     length,u
  201.         ldb     [wrkadr,u]
  202.         stb     byte1,u
  203.         andb    #$88
  204.         beq     op18
  205.         cmpb    #$88
  206.         bne     op11
  207. op18    ldb     byte1,u
  208.         lsrb
  209.         lsrb
  210.         lsrb
  211.         lsrb
  212.         bsr     reg
  213.         cmpa    #'*
  214.         beq     op11
  215.         lda     #',
  216.         lbsr    putch
  217.         ldb     byte1,u
  218.         bsr     reg
  219.         cmpa    #'*
  220.         beq     op11
  221.         bra     op16
  222. reg     andb    #$0f
  223.         leax    regtab,pc
  224.         lda     b,x
  225.         lbsr    putch
  226.         cmpb    #$05
  227.         bne     reg1
  228.         lda     #'c
  229.         bra     reg3
  230. reg1    cmpb    #$0a
  231.         bne     reg2
  232.         lda     #'c
  233.         bra     reg3
  234. reg2    cmpb    #$0b
  235.         bne     reg4
  236.         lda     #'p
  237. reg3    lbsr    putch
  238. reg4    rts
  239. op20    ldb     page1,u
  240.         cmpb    #$11
  241.         beq     op21
  242.         cmpa    #$20
  243.         bne     op22
  244.         cmpb    #$00
  245.         beq     op22
  246. op21    lbra    ilegop
  247. op22    cmpb    #$10
  248.         bne     op26
  249. op23    ldb     #3
  250.         leax    mnem+2,u
  251. op24    lda     ,x+
  252.         sta     ,x
  253.         leax    -2,x
  254.         decb
  255.         bne     op24
  256.         lda     #'l
  257.         sta     1,x
  258.         lbsr    rel16
  259. op25    lbra    finish
  260. op26    lbsr    rel8
  261.         bra     op25
  262. op30    ldb     page1,u
  263.         cmpa    #$3f
  264.         beq     op301
  265.         cmpb    #0
  266.         beq     op32
  267.         lbra    ilegop
  268. op32    cmpa    #$33
  269.         bhi     op34
  270.         lbsr    index
  271. op33    lbra    finish
  272. op34    cmpa    #$3c
  273.         beq     op302
  274.         cmpa    #$37
  275.         bhi     op33
  276.         inc     length,u
  277.         lda     [wrkadr,u]
  278.         sta     byte1,u
  279.         sta     byte2,u
  280.         clrb
  281. op35    lsl     byte2,u
  282.         bcc     op300
  283.         leax    stktab,pc
  284.         lda     b,x
  285.         cmpa    #'s
  286.         bne     op36
  287.         cmpa    mnem+3,u
  288.         bne     op36
  289.         lda     #'u
  290. op36    lbsr    putch
  291.         cmpa    #'p
  292.         beq     op37
  293.         cmpa    #'c
  294.         bne     op38
  295. op37    lda     #'c
  296.         lbsr    putch
  297.         bra     op39
  298. op38    cmpa    #'d
  299.         bne     op39
  300.         lda     #'p
  301.         lbsr    putch
  302.         bra     op39
  303. op39    lda     #',
  304.         lbsr    putch
  305. op300   incb
  306.         cmpb    #8
  307.         bne     op35
  308.         ldx     nxtbuf,u
  309.         leax    -1,x
  310.         stx     nxtbuf,u
  311.         bra     op33
  312. op301   cmpb    #0
  313.         beq     op33
  314.         addb    #$21
  315.         stb     mnem+3,u
  316.         bra     op33
  317. op302   lda     #'#
  318.         lbsr    putch
  319.         lbsr    direct
  320.         lbra    finish
  321. op80    ldb     page1,u
  322.         cmpa    #$8d
  323.         bne     op81
  324.         cmpb    #$00
  325.         lbne    ilegop
  326.         lda     #'b
  327.         sta     mnem,u
  328.         lbsr    rel8
  329.         lbra    finish
  330. op81    anda    #$8f
  331.         cmpa    #$83
  332.         bne     op83
  333.         cmpb    #$00
  334.         beq     op800
  335.         lda     #'c
  336.         sta     mnem,u
  337.         lda     #'m
  338.         sta     mnem+1,u
  339.         lda     #'p
  340.         sta     mnem+2,u
  341.         lda     #'d
  342.         cmpb    #$10
  343.         beq     op82
  344.         lda     #'u
  345. op82    sta     mnem+3,u
  346.         bra     op800
  347. op83    cmpa    #$8c
  348.         bne     op85
  349.         cmpb    #$00
  350.         beq     op800
  351.         lda     #'y
  352.         cmpb    #$10
  353.         beq     op84
  354.         lda     #'s
  355. op84    sta     mnem+3,u
  356.         bra     op800
  357. op85    cmpa    #$8e
  358.         blo     op86
  359.         cmpb    #$11
  360.         lbeq    ilegop
  361.         cmpb    #$00
  362.         beq     op800
  363.         lda     #'y
  364.         sta     mnem+2,u
  365.         bra     op800
  366. op86    cmpb    #$00
  367.         lbne    ilegop
  368. op800   lda     opcd,u
  369.         anda    #$bf
  370.         cmpa    #$87
  371.         beq     op801
  372.         cmpa    #$8d
  373.         beq     op801
  374.         cmpa    #$8f
  375.         bne     op802
  376. op801   lbra    ilegop
  377. op802   lda     opcd,u
  378.         anda    #$30
  379.         cmpa    #$30
  380.         bne     op803
  381.         lbsr    extend
  382.         lbra    finish
  383. op803   cmpa    #$20
  384.         bne     op804
  385.         lbsr    index
  386.         lbra    finish
  387. op804   cmpa    #$10
  388.         bne     op805
  389.         lbsr    direct
  390.         lbra    finish
  391. op805   lda     #'#
  392.         lbsr    putch
  393.         lda     opcd,u
  394.         anda    #$8f
  395.         cmpa    #$83
  396.         beq     op806
  397.         cmpa    #$8c
  398.         bhs     op806
  399.         lbsr    direct
  400.         lbra    finish
  401. op806   lbsr    extend
  402.         lbra    finish
  403. opc0    ldb     page1,u
  404.         anda    #$cf
  405.         cmpa    #$cb
  406.         bhi     opc3
  407.         cmpa    #$c3
  408.         bne     opc0a
  409.         lda     #'a
  410.         sta     mnem,u
  411.         lda     #'d
  412.         sta     mnem+1,u
  413.         sta     mnem+2,u
  414.         sta     mnem+3,u
  415.         bra     opc2
  416. opc0a   leax    mnem+2,u
  417.         lda     ,x
  418.         cmpa    #'a
  419.         beq     opc1
  420.         leax    1,x
  421. opc1    inc     ,x
  422. opc2    cmpb    #$00
  423.         beq     opc8
  424.         bra     ilegop
  425. opc3    cmpa    #$cd
  426.         bhi     opc6
  427.         bne     opc5
  428.         lda     #'s
  429.         sta     mnem,u
  430.         lda     #'t
  431. opc4    sta     mnem+1,u
  432.         lda     #'d
  433.         sta     mnem+2,u
  434.         lda     #$20
  435.         sta     mnem+3,u
  436.         bra     opc2
  437. opc5    lda     #'l
  438.         sta     mnem,u
  439.         lda     #'d
  440.         bra     opc4
  441. opc6    cmpb    #$11
  442.         beq     ilegop
  443.         lda     #'u
  444.         cmpb    #$00
  445.         beq     opc7
  446.         lda     #'s
  447. opc7    sta     mnem+2,u
  448. opc8    lbra    op800
  449. ilegop  leax    mnileg,pc
  450.         leay    mnem,u
  451.         ldb     #4
  452. ilop1   lda     ,x+
  453.         sta     ,y+
  454.         decb
  455.         bne     ilop1
  456.         leax    1,y
  457.         stx     nxtbuf,u
  458.         lda     #1
  459.         sta     length,u
  460.         lbra    finish
  461. index   inc     length,u
  462.         ldx     wrkadr,u
  463.         ldb     ,x+
  464.         stx     wrkadr,u
  465.         stb     indbyt,u
  466.         stb     byte1,u
  467.         andb    #$90
  468.         cmpb    #$90
  469.         bne     ind1
  470.         com     indflg,u
  471.         lda     #'[
  472.         lbsr    putch
  473. ind1    ldb     indbyt,u
  474.         andb    #$8f
  475.         cmpb    #$80
  476.         blo     ind5
  477.         cmpb    #$83
  478.         bhi     ind5
  479.         lda     indbyt,u
  480.         anda    #$11
  481.         cmpa    #$10
  482.         beq     ilegop
  483.         lda     #',
  484.         lbsr    putch
  485.         cmpb    #$81
  486.         bhi     ind3
  487.         lbsr    getreg
  488.         lda     #'+
  489.         lbsr    putch
  490.         cmpb    #$81
  491.         bne     ind2
  492.         lbsr    putch
  493. ind2    lbra    indend
  494. ind3    lda     #'-
  495.         lbsr    putch
  496.         cmpb    #$83
  497.         bne     ind4
  498.         lbsr    putch
  499. ind4    lbsr    getreg
  500.         lbra    indend
  501. ind5    lda     #'a
  502.         cmpb    #$86
  503.         beq     ind6
  504.         lda     #'b
  505.         cmpb    #$85
  506.         beq     ind6
  507.         lda     #'d
  508.         cmpb    #$8b
  509.         bne     ind7
  510. ind6    lbsr    putch
  511.         lda     #',
  512.         lbsr    putch
  513.         lbsr    getreg
  514.         lbra    indend
  515. ind7    cmpb    #$8d
  516.         beq     ind8
  517.         cmpb    #$8c
  518.         bne     ind10
  519. ind8    lda     indbyt,u
  520.         sta     postb,u
  521.   ;inc     length
  522.         cmpb    #$8d
  523.         beq     ind9
  524.         lbsr    rel8
  525. ind8a   lda     #',
  526.         lbsr    putch
  527.         lda     #'p
  528.         lbsr    putch
  529.         lda     #'c
  530.         lbsr    putch
  531.         lbra    indend
  532. ind9    lbsr    rel16
  533.         bra     ind8a
  534. ind10   cmpb    #$84
  535.         bne     ind12
  536.         clra
  537. ind11   lbsr    put2h
  538.         lda     #',
  539.         lbsr    putch
  540.         bsr     getreg
  541.         lbra    indend
  542. ind12   bitb    #$80
  543.         bne     ind13
  544.         tst     indflg,u
  545.         bne     ind18
  546.         ldb     indbyt,u
  547.         andb    #$1f
  548.         bitb    #$10
  549.         beq     ind12a
  550.         lda     #'-
  551.         lbsr    putch
  552.         orb     #$e0
  553.         negb
  554. ind12a  tfr     b,a
  555.         bra     ind11
  556. ind13   lda     indbyt,u
  557.         sta     postb,u
  558.         cmpb    #$88
  559.         bne     ind15
  560.         inc     length,u
  561.         ldb     [wrkadr,u]
  562.         stb     byte1,u
  563.         bpl     ind14
  564.         lda     #'-
  565.         lbsr    putch
  566.         negb
  567. ind14   tfr     b,a
  568.         bra     ind11
  569. ind15   cmpb    #$89
  570.         bne     ind16
  571.         inc     length,u
  572.         inc     length,u
  573.         ldd     [wrkadr,u]
  574.         std     byte1,u
  575.         lbsr    put2h
  576.         tfr     b,a
  577.         bra     ind11
  578. ind16   lda     indbyt,u
  579.         cmpa    #$9f
  580.         bne     ind18
  581.         sta     postb,u
  582.         bsr     extend
  583.         bra     indend
  584. ind18   lbra    ilegop
  585. getreg  pshs    b
  586.         ldb     indbyt,u
  587.         lda     #'x
  588.         andb    #$60
  589.         beq     getr1
  590.         lda     #'y
  591.         cmpb    #$20
  592.         beq     getr1
  593.         lda     #'u
  594.         cmpb    #$40
  595.         beq     getr1
  596.         lda     #'s
  597. getr1   lbsr    putch
  598.         puls    b
  599.         rts
  600. indend  tst     indflg,u
  601.         beq     inden1
  602.         lda     #']
  603.         lbsr    putch
  604. inden1  rts
  605. direct  inc     length,u
  606.         lda     #$24
  607.         bsr     putch
  608.         lda     [wrkadr,u]
  609.         sta     byte1,u
  610.         bsr     put2h
  611.         rts
  612. extend  bsr     direct
  613.         inc     length,u
  614.         inc     wrkadr+1,u
  615.         bne     ext1
  616.         inc     wrkadr,u
  617. ext1    lda     [wrkadr,u]
  618.         sta     byte2,u
  619.         bsr     put2h
  620.         rts
  621. rel8    inc     length,u
  622.         lda     #'(
  623.         bsr     putch
  624.         lda     [wrkadr,u]
  625.         tfr     a,b
  626.         sta     byte1,u
  627.         sex
  628.         addd    #1
  629. rel8a   addd    wrkadr,u
  630.         bsr     put2h
  631.         tfr     b,a
  632.         bsr     put2h
  633.         lda     #')
  634.         bsr     putch
  635.         rts
  636. rel16   inc     length,u
  637.         inc     length,u
  638.         lda     #'(
  639.         bsr     putch
  640.         ldd     [wrkadr,u]
  641.         sta     byte1,u
  642.         stb     byte2,u
  643.         addd    #2
  644.         bra     rel8a
  645. put2h   pshs    a
  646.         bsr     put2hl
  647.         puls    a
  648.         bsr     put2hr
  649.         rts
  650. put2hl  lsra
  651.         lsra
  652.         lsra
  653.         lsra
  654. put2hr  anda    #$f
  655.         adda    #'0
  656.         cmpa    #'9
  657.         bls     putch
  658.         adda    #7
  659. putch   ldx     nxtbuf,u
  660.         sta     ,x+
  661.         stx     nxtbuf,u
  662.         rts
  663. finish  lda     #$0d
  664.         bsr     putch
  665.         leax    buffer,u
  666.         stx     nxtbuf,u
  667.         lda     curadr,u
  668.         bsr     put2h
  669.         lda     curadr+1,u
  670.         bsr     put2h
  671.         lda     #$20
  672.         bsr     putch
  673.         lda     length,u
  674.         pshs    a
  675.         lda     page1,u
  676.         beq     eoj1
  677.         bsr     put2h
  678.         dec     length,u
  679. eoj1    leax    buffer+7,u
  680.         stx     nxtbuf,u
  681.         lda     opcd,u
  682.         bsr     put2h
  683.         dec     length,u
  684.         lda     postb,u
  685.         beq     eoj2
  686.         bsr     put2h
  687.         dec     length,u
  688. eoj2    leax    hexb,u
  689.         stx     nxtbuf,u
  690.         tst     length,u
  691.         beq     eoj4
  692.         lda     byte1,u
  693.         lbsr    put2h
  694.         dec     length,u
  695.         beq     eoj4
  696.         lda     byte2,u
  697.         lbsr    put2h
  698.         opt     list
  699. eoj4    leax    buffer,u
  700.         ldb     #$27
  701.         stb     length,u
  702. eoj5    ldb     ,x+
  703.         dec     length,u
  704.         cmpb    #$0d
  705.         beq     asciii
  706.         bsr     outb
  707.         bra     eoj5
  708. asciii  ldb     #$20        ;use blanks to separate
  709.         bsr     outb        ;   ascii print out from
  710.         dec     length,u    ;   disassembly
  711.         bne     asciii
  712.         leax    buffer+5,u  ;output ascii
  713.         bsr     pack1       ;get 7x2 bytes
  714.         ldb     #$0d
  715.         bsr     outb
  716.         puls    b
  717.         sex
  718.         addd    curadr,u
  719.         std     curadr,u
  720.         ldx     curadr,u
  721.         leas    endbuf-outch,u
  722.         puls    a,b,y,u
  723.         rts
  724. outb    pshs    x
  725.         jsr     putchar_
  726.         puls    x
  727.         rts
  728. pack1   lda     #$9
  729. packit  pshs    a
  730.         ldb     ,x+
  731.         bsr     ascnib
  732.         cmpb    #$20
  733.         beq     blank
  734.         exg     a,b     ;save nibble in a
  735.         ldb     ,x+
  736.         bsr     ascnib
  737.         cmpb    #$20
  738.         beq     blank
  739.         lslb
  740.         lslb
  741.         lslb
  742.         lslb
  743.         lslb
  744.         rola
  745.         lslb
  746.         rola
  747.         lslb
  748.         rola
  749.         lslb
  750.         rola
  751.         exg     a,b     ;two nibbles in b
  752.         cmpb    #$20
  753.         blo     blank
  754.         cmpb    #$7e
  755.         bhi     blank
  756.         bra     blnk
  757. blank   ldb     #$20
  758. blnk    bsr     outb
  759.         puls    a
  760.         deca
  761.         bne     packit
  762.         rts
  763. ascnib  cmpb    #$46
  764.         bhi     nogood
  765.         cmpb    #$30
  766.         blo     nogood
  767.         cmpb    #$3a
  768.         blo     good
  769.         cmpb    #$41
  770.         blo     nogood
  771.         subb    #$7
  772. good    andb    #$0f
  773.         rts
  774. nogood  ldb     #$20
  775.         rts
  776. regtab  fcc     "dxyusp**abcd****"
  777. stktab  fcc     "psyxdbac"
  778. mntab   fcc     "neg "
  779. mnileg  fcc     "*** "
  780.         fcc     "*** "
  781.         fcc     "com "
  782.         fcc     "lsr "
  783.         fcc     "*** "
  784.         fcc     "ror "
  785.         fcc     "asr "
  786.         fcc     "asl "
  787.         fcc     "rol "
  788.         fcc     "dec "
  789.         fcc     "*** "
  790.         fcc     "inc "
  791.         fcc     "tst "
  792.         fcc     "jmp "
  793.         fcc     "clr "
  794.         fcc     "*** "
  795.         fcc     "*** "
  796.         fcc     "nop "
  797.         fcc     "sync"
  798.         fcc     "*** "
  799.         fcc     "*** "
  800.         fcc     "bra "
  801.         fcc     "bsr "
  802.         fcc     "*** "
  803.         fcc     "daa "
  804.         fcc     "orcc"
  805.         fcc     "*** "
  806.         fcc     "andc"
  807.         fcc     "sex "
  808.         fcc     "exg "
  809.         fcc     "tfr "
  810.         fcc     "bra "
  811.         fcc     "brn "
  812.         fcc     "bhi "
  813.         fcc     "bls "
  814.         fcc     "bhs "
  815.         fcc     "blo "
  816.         fcc     "bne "
  817.         fcc     "beq "
  818.         fcc     "bvc "
  819.         fcc     "bvs "
  820.         fcc     "bpl "
  821.         fcc     "bmi "
  822.         fcc     "bge "
  823.         fcc     "blt "
  824.         fcc     "bgt "
  825.         fcc     "ble "
  826.         fcc     "leax"
  827.         fcc     "leay"
  828.         fcc     "leas"
  829.         fcc     "leau"
  830.         fcc     "pshs"
  831.         fcc     "puls"
  832.         fcc     "pshu"
  833.         fcc     "pulu"
  834.         fcc     "*** "
  835.         fcc     "rts "
  836.         fcc     "abx "
  837.         fcc     "rti "
  838.         fcc     "cwai"
  839.         fcc     "mul "
  840.         fcc     "*** "
  841.         fcc     "swi "
  842.         fcc     "suba"
  843.         fcc     "cmpa"
  844.         fcc     "sbca"
  845.         fcc     "subd"
  846.         fcc     "anda"
  847.         fcc     "bita"
  848.         fcc     "lda "
  849.         fcc     "sta "
  850.         fcc     "eora"
  851.         fcc     "adca"
  852.         fcc     "ora "
  853.         fcc     "adda"
  854.         fcc     "cmpx"
  855.         fcc     "jsr "
  856.         fcc     "ldx "
  857.         fcc     "stx "
  858.         end
  859.